mirror of
https://github.com/yuzu-emu/yuzu.git
synced 2024-07-04 23:31:19 +01:00
da14c7b8e4
Replaces every way of handling config for each frontend with SimpleIni. frontend_common's Config class is at the center where it saves and loads all of the cross-platform settings and provides a set of pure virtual functions for platform specific settings. As a result of making config handling platform specific, several parts had to be moved to each platform's own config class or to other parts. Default keys were put in platform specific config classes and translatable strings for Qt were moved to shared_translation. Default hotkeys, default_theme, window geometry, and qt metatypes were moved to uisettings. Additionally, to reduce dependence on Qt, QStrings were converted to std::strings where applicable.
65 lines
2.2 KiB
CMake
65 lines
2.2 KiB
CMake
# SPDX-FileCopyrightText: 2018 yuzu Emulator Project
|
|
# SPDX-License-Identifier: GPL-2.0-or-later
|
|
|
|
# Credits to Samantas5855 and others for this function.
|
|
function(create_resource file output filename)
|
|
# Read hex data from file
|
|
file(READ ${file} filedata HEX)
|
|
# Convert hex data for C compatibility
|
|
string(REGEX REPLACE "([0-9a-f][0-9a-f])" "0x\\1," filedata ${filedata})
|
|
# Write data to output file
|
|
set(RESOURCES_DIR "${PROJECT_BINARY_DIR}/dist" PARENT_SCOPE)
|
|
file(WRITE "${PROJECT_BINARY_DIR}/dist/${output}" "const unsigned char ${filename}[] = {${filedata}};\nconst unsigned ${filename}_size = sizeof(${filename});\n")
|
|
endfunction()
|
|
|
|
add_executable(yuzu-cmd
|
|
emu_window/emu_window_sdl2.cpp
|
|
emu_window/emu_window_sdl2.h
|
|
emu_window/emu_window_sdl2_gl.cpp
|
|
emu_window/emu_window_sdl2_gl.h
|
|
emu_window/emu_window_sdl2_null.cpp
|
|
emu_window/emu_window_sdl2_null.h
|
|
emu_window/emu_window_sdl2_vk.cpp
|
|
emu_window/emu_window_sdl2_vk.h
|
|
precompiled_headers.h
|
|
sdl_config.cpp
|
|
sdl_config.h
|
|
yuzu.cpp
|
|
yuzu.rc
|
|
)
|
|
|
|
create_target_directory_groups(yuzu-cmd)
|
|
|
|
target_link_libraries(yuzu-cmd PRIVATE inih::INIReader glad)
|
|
target_link_libraries(yuzu-cmd PRIVATE common core input_common frontend_common)
|
|
if (MSVC)
|
|
target_link_libraries(yuzu-cmd PRIVATE getopt)
|
|
endif()
|
|
target_link_libraries(yuzu-cmd PRIVATE ${PLATFORM_LIBRARIES} Threads::Threads)
|
|
|
|
create_resource("../../dist/yuzu.bmp" "yuzu_cmd/yuzu_icon.h" "yuzu_icon")
|
|
target_include_directories(yuzu-cmd PRIVATE ${RESOURCES_DIR})
|
|
|
|
target_link_libraries(yuzu-cmd PRIVATE SDL2::SDL2 Vulkan::Headers)
|
|
|
|
if(UNIX AND NOT APPLE)
|
|
install(TARGETS yuzu-cmd)
|
|
endif()
|
|
|
|
if(WIN32)
|
|
# compile as a win32 gui application instead of a console application
|
|
if(MSVC)
|
|
set_target_properties(yuzu-cmd PROPERTIES LINK_FLAGS_RELEASE "/SUBSYSTEM:WINDOWS /ENTRY:mainCRTStartup")
|
|
elseif(MINGW)
|
|
set_target_properties(yuzu-cmd PROPERTIES LINK_FLAGS_RELEASE "-Wl,--subsystem,windows")
|
|
endif()
|
|
endif()
|
|
|
|
if (MSVC)
|
|
include(CopyYuzuSDLDeps)
|
|
copy_yuzu_SDL_deps(yuzu-cmd)
|
|
endif()
|
|
|
|
if (YUZU_USE_PRECOMPILED_HEADERS)
|
|
target_precompile_headers(yuzu-cmd PRIVATE precompiled_headers.h)
|
|
endif()
|