mirror of
https://git.suyu.dev/suyu/dynarmic.git
synced 2025-03-04 13:16:04 +00:00
9af5f5908c
913099fc8 v6.60.1 d3910abbe update doc 7ac6b37fd Merge branch 'dev' 72c4b8ad5 refactoring e649372b6 modify definition of Type for Visual Studio with /O0 e9cec7582 Merge branch 'dev' 153b40ed1 update changelog f0c522af8 v6.60 553246c16 the version format has changed from A.BC(D) to A.BC(.D) git-subtree-dir: externals/xbyak git-subtree-split: 913099fc80e80f01fc0877c6016b9dd8cf1f0322
55 lines
1.5 KiB
CMake
55 lines
1.5 KiB
CMake
cmake_minimum_required(VERSION 2.6...3.0.2)
|
|
|
|
project(xbyak LANGUAGES CXX VERSION 6.60.1)
|
|
|
|
file(GLOB headers xbyak/*.h)
|
|
|
|
if (DEFINED CMAKE_VERSION AND CMAKE_VERSION VERSION_GREATER_EQUAL 3.0.2)
|
|
include(GNUInstallDirs)
|
|
add_library(${PROJECT_NAME} INTERFACE)
|
|
add_library(${PROJECT_NAME}::${PROJECT_NAME} ALIAS ${PROJECT_NAME})
|
|
|
|
target_include_directories(
|
|
${PROJECT_NAME} INTERFACE
|
|
"$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>"
|
|
"$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
|
|
)
|
|
|
|
install(
|
|
TARGETS ${PROJECT_NAME}
|
|
EXPORT ${PROJECT_NAME}-targets
|
|
INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME}
|
|
)
|
|
|
|
include(CMakePackageConfigHelpers)
|
|
configure_package_config_file(
|
|
cmake/config.cmake.in
|
|
"${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-config.cmake"
|
|
INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
|
|
)
|
|
write_basic_package_version_file(
|
|
"${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-config-version.cmake"
|
|
COMPATIBILITY SameMajorVersion
|
|
)
|
|
|
|
install(
|
|
FILES
|
|
"${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-config.cmake"
|
|
"${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-config-version.cmake"
|
|
DESTINATION
|
|
${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
|
|
)
|
|
|
|
install(
|
|
EXPORT ${PROJECT_NAME}-targets
|
|
NAMESPACE ${PROJECT_NAME}::
|
|
DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
|
|
)
|
|
elseif(NOT DEFINED CMAKE_INSTALL_INCLUDEDIR)
|
|
set(CMAKE_INSTALL_INCLUDEDIR "include")
|
|
endif()
|
|
|
|
install(
|
|
FILES ${headers}
|
|
DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/xbyak
|
|
)
|